Проблема Бензин /fill

[Marvellous 271]

Всем привет! В чем может быть проблема?

 

Помогите пожалуйста!

 

Смотрите, приезжает игрок на АЗС водит /buyfuel и ему выдается окно

 

Бензин

Канистра

Инструменты

 

Когда выбираешь бензин, там выдает окно,типо сколько литров,пишешь любое количество и нажимаешь оплатить  и тупо списываются деньги и все, но бензин не заправился! В чем может быть проблема?

 

Вот вроде бы весь код!

dialog_BUYFUEL_1,

case dialog_BUYFUEL:
		{
			if(!response) return true;
			if(response)
			{
				switch(listitem)
				{
				    case 0:
				    {
				        new dtext[110],b = GetPVarInt(playerid, "business");
						format(dtext,sizeof(dtext),"{FFFFFF}Стоимость бензина: %d рублей за 1 литр\nВведите количество бензина которое хотите приобрести",BUSINESS_DATA[b][data_CENA]);
						ShowPlayerDialogFix(playerid, dialog_BUYFUEL_1, DIALOG_STYLE_INPUT, "{FFCC00}Бензин",dtext, "Купить", "Отмена");
				    }
				    case 1:
				    {
				        new dtext[110],b = GetPVarInt(playerid, "business");
						format(dtext,sizeof(dtext),"{FFFFFF}Вы желаете купить канисту с бензином? Стоимость: %d рублей",BUSINESS_DATA[b][data_CENA]*20);
						ShowPlayerDialogFix(playerid, dialog_BUYFUEL_2, DIALOG_STYLE_MSGBOX, "{FFCC00}Канистра",dtext, "Купить", "Отмена");
				    }
				    case 2:
				    {
				        new dtext[110],b = GetPVarInt(playerid, "business");
						format(dtext,sizeof(dtext),"{FFFFFF}Вы желаете купить комплект запчастей? Стоимость: %d рублей",BUSINESS_DATA[b][data_CENA]*30);
					   	ShowPlayerDialogFix(playerid, dialog_BUYFUEL_3, DIALOG_STYLE_MSGBOX, "{FFCC00}Запчасти",dtext, "Купить", "Отмена");
				    }
				}
			}
		}

case dialog_BUYFUEL_1:
		{
			if(!response) return true;
			if(response)
			{
	  			if(IsPlayerInAnyVehicle(playerid) && GetPlayerState(playerid) == PLAYER_STATE_DRIVER)
				{
				    new b = GetPVarInt(playerid,"business");
		   			new cena = BUSINESS_DATA[b][data_CENA]*strval(inputtext);
				    new car = GetPlayerVehicleID(playerid);
		   			if(strval(inputtext) <= 0) return SendClientMessage(playerid, COLOR_WARNING, "Недопустимое значение!");
					if(strval(inputtext)+CAR_DATA[car][data_FUEL] > 50) return SendClientMessage(playerid, COLOR_WARNING, "Допустимо максимум 50 литров в баке!");
                    if(strval(inputtext) > BUSINESS_DATA[b][data_PROD]  && BUSINESS_DATA[b][data_OWNED] == 1) return SendClientMessage(playerid,COLOR_WARNING,"Недостаточно топлива на складе!");
					if(get_player_money(playerid) < cena) return SendClientMessage(playerid,COLOR_WARNING,"У Вас недостаточно денег на руках!");

                    BUSINESS_DATA[b][data_PROD] -= strval(inputtext);
					BUSINESS_DATA[b][data_BANK] += cena;
					give_player_money(playerid,-cena,"#28");
					CAR_DATA[playerid][data_FUEL] += strval(inputtext);
					UpdateBusinessData(b);
					
					new ftext[15];
					format(ftext, sizeof(ftext),"fuel: %d", CAR_DATA[car][data_FUEL]);
					PlayerTextDrawSetString(playerid,SpeedometrFuel[playerid],ftext);
        
        
				}
			}
		}

stock UpdateBusinessData(b)
{
	new str[256];
    if(BUSINESS_DATA[b][data_TYPE] == 1)
	{
	    if(BUSINESS_DATA[b][data_OWNED] == 1)
		{
		    new mafia[16];
			switch(BUSINESS_DATA[b][data_MAFIA])
			{
				case 5: mafia = "Трамповское ОПГ";
				case 6: mafia = "Майкопское ОПГ";
				case 7: mafia = "Одесское ОПГ";
				default: mafia = "Нет";
			}
	    	format(str,sizeof(str), "{3399FF}%s\n{CCFF00}Владелец: {FFFFFF}%s\n{CCFF00}Топлива: {FFFFFF}%i л\n{CCFF00}Цена за 1 л: {FFFFFF}%i рублей\n{CCFF00}Закупочная цена: {FFFFFF}%i рублей\n{CCFF00}Крыша: {FFFFFF}%s\n{339966}/buyfuel",BUSINESS_DATA[b][data_NAME],BUSINESS_DATA[b][data_OWNER],BUSINESS_DATA[b][data_PROD],BUSINESS_DATA[b][data_CENA],BUSINESS_DATA[b][data_PRICEPROD],mafia);
     		UpdateDynamic3DTextLabelText(BUSINESS_DATA[b][data_TEXTINFO], -1, str);
		}
		else
		{
			format(str,sizeof(str), "{3399FF}%s\n{CCFF00}Стоимость бизнеса: {FFFFFF}%i рублей\n{CCFF00}Для покупки бизнеса используйте: {FFFFFF}/buy",BUSINESS_DATA[b][data_NAME],BUSINESS_DATA[b][data_PRICE]);
			UpdateDynamic3DTextLabelText(BUSINESS_DATA[b][data_TEXTINFO], -1, str);
		}
	}
	else
	{
		if(BUSINESS_DATA[b][data_OWNED] == 1)
		{
		    new mafia[16];
			switch(BUSINESS_DATA[b][data_MAFIA])
			{
				case 5: mafia = "Трамповское ОПГ";
				case 6: mafia = "Майкопское ОПГ";
				case 7: mafia = "Одесское ОПГ";
				default: mafia = "Нет";
			}
			format(str,sizeof(str), "{3399FF}%s\n{CCFF00}Владелец: {FFFFFF}%s\n{CCFF00}Продуктов: {FFFFFF}%i шт\n{CCFF00}Цена покупки продуктов: {FFFFFF}%i рублей\n{CCFF00}Крыша: {FFFFFF}%s\n{FE2E2E}Вход бесплатный",BUSINESS_DATA[b][data_NAME],BUSINESS_DATA[b][data_OWNER],BUSINESS_DATA[b][data_PROD],BUSINESS_DATA[b][data_PRICEPROD],mafia);
			UpdateDynamic3DTextLabelText(BUSINESS_DATA[b][data_TEXTINFO], -1, str);
		}
		else
		{
			format(str,sizeof(str), "{3399FF}%s\n{CCFF00}Стоимость бизнеса: {FFFFFF}%i рублей\n{CCFF00}Для покупки бизнеса используйте: {FFFFFF}/buy",BUSINESS_DATA[b][data_NAME],BUSINESS_DATA[b][data_PRICE]);
			UpdateDynamic3DTextLabelText(BUSINESS_DATA[b][data_TEXTINFO], -1, str);
		}
	}
	return true;
}

[#GOBLIN 95]

Обновлять транспорт не пробовал? Типо как бизнес

[Marvellous 271]

@#GOBLIN, В каком смысле? Не понял! 

[Marvellous 271]

АП

[SCRIPTMAN 358]

CAR_DATA[playerid][data_FUEL] += strval(inputtext);

на

CAR_DATA[car][data_FUEL] += strval(inputtext);

Какие-то невнимательные мы))